Essays, Posts & Presentations

Democratic Presidential Debate Analysis Using the Wolfram Language

Brian Wood

Author

Brian Wood

Title

Democratic Presidential Debate Analysis Using the Wolfram Language

Description

Computational exploration of the Democratic presidential debates. Measuring a "win" using the Wolfram Language to analyze debate transcripts and polling data.

Democratic Presidential Debate Analysis Using the Wolfram Language

February 6, 2020

Brian Wood, Lead Technical Writer, Document and Media Systems

When 20 presidential candidates duke it out on the debate stage, who wins? Americans have been watching a crowded and contentious primary season for the 2020 Democratic nomination for president. After the debates, everyone’s talking about who got the most talk time or attention, which exchanges were most exciting or some other measure of who “won” the night—and who might ultimately clinch a victory at the caucuses. So I decided I’d do a little exploration of the debates using the entity framework, text analytics and graph capabilities of the Wolfram Language and see if I could come up with my own measure of a “win” for a debate, based on which candidate was most central to the conversation.

Text Import: What Was Said? In a perfect world, the debate audio and video would be machine readable. But as it stands, we at least have access to the text in transcript form. Before we dive in, it’s helpful to be ready with a bit of preliminary info.

First, let’s retrieve a list of candidate names. Since candidates keep joining and dropping out, I built this list manually over time:

In[]:=

candidateNames={"Amy Klobuchar","Andrew Yang","Bernie Sanders","Beto O'Rourke","Bill De Blasio","Cory Booker","Elizabeth Warren","Eric Swalwell","Jay Inslee","Joe Biden","John Delaney","John Hickenlooper","Julián Castro","Kamala Harris","Kirsten Gillibrand","Marianne Williamson","Michael Bennet","Pete Buttigieg","Steve Bullock","Tim Ryan","Tulsi Gabbard","Tom Steyer"};

We can use

Interpreter

to see which candidates the Wolfram System recognizes—as it turns out, all of them:

In[]:=

candidates=Interpreter["Person"]@candidateNames

Out[]=



Amy Klobuchar

Andrew Yang

Bernie Sanders

Beto O'Rourke

Bill de Blasio

Cory Booker

Elizabeth Warren

Eric Swalwell

Jay Inslee

Joe Biden

John Delaney

John Hickenlooper

Julián Castro

Kamala Harris

Kirsten Gillibrand

Marianne Williamson

Michael Bennet

Pete Buttigieg

Steve Bullock

Tim Ryan

Tulsi Gabbard

Tom Steyer



For proper parsing of questions, we'll also want the names of the moderators (no entities required in this case):

In[]:=

modNames={"Lester Holt","Savannah Guthrie","Chuck Todd","Rachel Maddow","Jake Tapper","Dana Bash","Don Lemon","George Stephanopoulos","Jorge Ramos","Linsey Davis","David Muir","Anderson Cooper","Erin Burnett","Marc Lacey","Andrea Mitchell","Ashley Parker","Kristen Welker","Judy Woodruff","Yamiche Alcindor","Amna Nawaz","Tim Alberta","Jose Diaz-Balart","Wolf Blitzer","Abby Phillip","Brianne Pfannenstiel","ANNOUNCER"};

Finally, we combine these into a list of everyone who either spoke or was spoken to:

In[]:=

debateNames=Join[candidateNames,modNames];debatePeople=Join[candidates,modNames];

For navigating the transcript, it will also be useful to split into lists of first and last names:

In[]:=

{firstNames,lastNames}=Transpose[{First[#],StringRiffle@Rest@#}&/@StringSplit[debateNames]];

Transcripts can come from any number of outlets; fortunately, the formatting is fairly standard across sources. Importing the transcript is as easy as

Import

; we’ll start with the raw text from the most recent debate (January 14) as transcribed by Rev.com:

In[]:=

d7raw=Import["https://wolfr.am/K7dyQhOh"];

You can see on the website that every spoken line begins with the speaker’s name—with a few variations like “E. Warren”—followed by a colon and a timestamp, then the contents of the line. We can use

StringCases

to grab each of those elements (including all name variations, iconized for brevity) from the transcript:

In[]:=

d7Lines=StringTrim/@StringCasesStringReplaced7raw,

Name Variations

,Shortest[name:(debateNames)~~": "~~("("~~time:__~~")")~~__~~line__~~"\n"~~debateNames]{name,time,line},IgnoreCaseFalse,OverlapsTrue;

Each entry is a list containing those three elements:

In[]:=

RandomChoice[d7Lines]

Out[]=

{Brianne Pfannenstiel,40:50,Mayor Buttigieg, your response?}

Then we convert this into a chronological list of speakerline rules. Not every transcript I found had timestamps, so I’ve left them out of this data:

In[]:=

d7Data=(#1/.Thread[debateNamesdebatePeople])#3&@@@d7Lines;

Here’s an entry from that list:

In[]:=

RandomChoice[d7Data]

Out[]=

Amy Klobuchar

They think they own Washington. They don’t own me. And as president, I will get this done.

Although the steps varied, I was able to build these datasets for each debate transcript. Here is the full data from all seven debates so far:

In[]:=

allDebateData=CloudGet["https://wolfr.am/K7wv2AEd"];

Analysis: Who Spoke about What, and How Much? The cloud data gives us enough information to start exploring with computation. For example, people often judge the debate by who got the most speaking time. We can roughly estimate this using

WordCount

to see how many words each person spoke:

In[]:=

wordsSpoken[data_,person_]:=StringRiffle@Values[Select[data,First@#person&]]//WordCount

PieChart

of this data from the most recent debate shows a pretty even spread:

In[]:=

PieChart[wordsSpoken[d7Data,#]&/@candidates,ChartLabelscandidates]

Out[]=

We can also dive a bit deeper into the content of the candidates’ words. With

TextCases

, we can get specific people, places and concepts mentioned in each line of text:

In[]:=

entityMentions[data_,entType_String]:=Thread[data[[All,1]]Union/@TextCases[Values@data,entType"Interpretation",VerifyInterpretationTrue]]

We could use this to explore any number of trends, such as which companies were mentioned during a given debate:

Counts[Flatten@Values@entityMentions[d7Data,"Company"]]

Out[]=



Nafta

2,

Amazon

2,

Chevron

2,

McDonald's

1,

McKinsey

1,

Eli Lilly

1,

Dow Jones Industrial Average

1,

Petroamerica Oil Corp

1

Throughout the debates, several countries have also been discussed; viewing the data with

WordCloud

shows the recent emphasis on Iran and Afghanistan:

In[]:=

WordCloud[Most@Sort@Counts[Flatten@Values@entityMentions[d7Data,"Country"]]]

Out[]=

Since audiences seem to love watching politicians talk to and about each other, I thought it would be interesting to look at direct mentions of other candidates. We can use StringCases to determine when a candidate is referred to by first or last name, including former President Barack Obama and current President Donald Trump, both of whom are invoked quite often. This function finds such mentions, associating each text mention with a specific person:

In[]:=

peopleMentions[data_]:=Modulenames=

Name Variations

,mentions,rules,mentions=Union/@StringCases[data//Values,names];rules=ThreadnamesJoincandidates,

Presidents

;Thread/@Thread[Keys[data]mentions/.rules]//Flatten

Although this function could potentially return false positives (e.g. “Warren Buffet” matching “Elizabeth Warren”), I found this to be a rare enough occurrence that I didn’t try to account for it. In a broader conversational piece, this might be a bit more difficult.

Since the moderators are not crucial for this analysis, here is a function to get a list of only Democratic candidates mentioning each other (or Trump/Obama):

In[]:=

candidateMentions[data_]:=DeleteMissing[peopleMentions[data]/.Thread[modNamesMissing[]],1,2]

When applied across the full dataset, we see that the candidates have mentioned names nearly a thousand times:

In[]:=

allMentions=Flatten[candidateMentions/@allDebateData];Length[allMentions]

Out[]=

948

Out of curiosity, I had to see who has spoken about the two presidents most throughout the debates, so I made a quick function to count who mentioned a given person the most:

In[]:=

mostMentions[candidate_]:=Dataset@TakeLargest[Counts[Select[allMentions,#[[2]]candidate&]//Keys],UpTo@5]

In[]:=

RowmostMentions/@

Donald Trump

PERSON

Barack Obama

PERSON



Out[]=

Amy Klobuchar	62
Bernie Sanders	41
Elizabeth Warren	41
Kamala Harris	37
Pete Buttigieg	37

Joe Biden	30
Amy Klobuchar	14
Julián Castro	10
Kamala Harris	9
Elizabeth Warren	7

Amy Klobuchar has a lot to say about President Trump, whereas Obama gets a lot of name-drops from his former vice president, Joe Biden. Notably, between the two lists, we see all five of the current frontrunners (excluding Harris and Castro).

Here are all the self-mentions; amusingly, Biden talks about himself the most:

In[]:=

DeleteCases[Table[KeySelect[mostMentions[c]//Normal,MatchQ[#,c]&],{c,candidates}],<||>]//Dataset

Out[]=

Amy Klobuchar	2
Jay Inslee	2
Joe Biden	14
John Delaney	2
Julián Castro	2
Kamala Harris	4
Marianne Williamson	2

To narrow the focus even more, here is a function that gives a list of mentions between participants of a specific debate only—removing Trump and Obama, as well as self-references:

In[]:=

debateMentions[data_]:=SelectcandidateMentions[data],MatchQ[#[[2]],Alternatives@@Union@Keys[data]]&&FreeQ#[[2]],Alternatives@@

Presidents

&&!SameQ[#[[1]],#[[2]]]&

The result is a reduced list of rules that we can use for further exploration of the interactions in each individual debate.

Graphs: Who Was the Center of Attention? We’ve done a bit of text analysis and basic counting; now it’s time to switch gears to graph theory. If we think of the output from our previous function as a list of one-way connections between candidates (i.e. directed edges pointing from speaker to subject) we can easily display the resulting graph for a given debate:

In[]:=

Graph[debateMentions[d7Data],VertexLabels"Name"]

Out[]=

We can simplify this view by representing repeated mentions with edge weights, styling each edge accordingly. First, we need to convert repeated edges into weighted edges:

In[]:=

weighted=Graph[Union@debateMentions[d7Data],EdgeWeightValues@Counts[debateMentions[d7Data]]];

To apply styles to the edges, we need to get the weights using

PropertyValue

, use

Rescale

to get values appropriate for the styling functions and then apply the styles using

Property

In[]:=

edgeWeightStyledGraph[g_,styleFunc_List,ranges_List]:=Graph@Module[{edges=EdgeList[g],weights,weightsScaled,styles},weights=Table[PropertyValue[{g,e},EdgeWeight],{e,edges}];weightsScaled=Table[Rescale[weights,MinMax[weights],r],{r,ranges}];styles=Directive@@@Transpose[Thread/@Table[styleFunc[[i]][weightsScaled[[i]]],{i,Length[styleFunc]}]];Table[Property[edges[[i]],{EdgeStylestyles[[i]],EdgeWeightweights[[i]]}],{i,Length[edges]}]]

Here is the same graph, but with edges consolidated and resized based on weights:

In[]:=

Graph[edgeWeightStyledGraph[weighted,{Thickness},{{.002,.01}}],VertexLabels"Name"]

Combining these steps (and adding some color), we can make a function to display the graph in a compact way:

In[]:=

debateMentionsGraph[data_]:=With{g=Graph[debateMentions[data]//Union,EdgeWeightValues@Counts@debateMentions[data]]},GraphedgeWeightStyledGraph[g,{Thickness,Darker[RGBColor[0,0.68625,0.95295],#]&},{{.002,.01},{.5,0}}],

Options

[g]

These graphs give a nice visual summary of the exchanges in each debate. Note that the positioning of the candidates is not important here—just the edges and their styles. In the latest debate, you can see a pretty strong emphasis on Sanders and Warren, the two progressive candidates:

In[]:=

g=debateMentionsGraph[d7Data]

Out[]=

Most candidates have built-in images tied to their entities, so instead of labeling with names, we could also use faces:

In[]:=

facesOverlay[g_]:=Graphg,VertexSize1.1,VertexLabels

Image Labels

[g]

In[]:=

facesOverlay[g]

Out[]=

Applying this to the first debate makes for an interesting—but crowded—graphic:

In[]:=

facesOverlay[debateMentionsGraph[allDebateData[[1]]]]

Out[]=

Next, we can explore

DegreeCentrality

: the relative number of edges connected to each vertex. In a directed graph, we can look at either in-degrees (a candidate being spoken about) or out-degrees (a candidate speaking about others). A high in-degree might indicate popularity, whereas a high out-degree would imply assertiveness. So for this exploration, we’ll consider both:

In[]:=

Thread[VertexList[g]Transpose@Table[DegreeCentrality[g,i],{i,{"In","Out"}}]]

Out[]=



Amy Klobuchar

{1,3},

Bernie Sanders

{4,3},

Elizabeth Warren

{3,2},

Pete Buttigieg

{2,0},

Joe Biden

{2,2},

Tom Steyer

{3,5}

By these numbers alone, we might give a win to Bernie Sanders for assertiveness or Tom Steyer for popularity. But we can take a more visual look by overlaying the data on our graph. First we compute both measures for each vertex:

In[]:=

centralityList[g_]:=Table[DegreeCentrality[g,i],{i,{"In","Out"}}]

Then we use

Blend

to define a color for each vertex (candidate)—

Blue

for in-degrees (popularity) and

Red

for out-degrees (assertiveness):

In[]:=

colorList[g_]:=Blend

,#&/@Transpose@centralityList[g]

Combining this with our existing function, we can make a new function to display the graph with vertex colors based on that blend:

In[]:=

mentionsCentralityGraph[data_]:=With[{g=debateMentionsGraph[data]},Graph[g,{VertexLabelStyleThread[VertexList[g]colorList[g]]}]]

Let’s take another look at the most recent debate:

In[]:=

mentionsCentralityGraph[d7Data]

Out[]=

The story here is clear: Sanders and Warren (purple) were at the core of numerous exchanges, with additional commentary from Biden and Steyer (who actually mentioned everyone). Klobuchar called out others but was barely named, whereas Buttegieg was mentioned but didn’t talk about others. By a “balanced” criterion (high assertiveness and popularity scores), Sanders and Warren appear to be the winners.

Let’s look back a bit further at the fifth debate, which aired on November 20:

In[]:=

mentionsCentralityGraph[allDebateData[[5]]]

Out[]=

One thing is evident: more candidates lead to fewer overall mentions. This makes sense from a logistical standpoint—each person has less time to speak—but I think it also shows the growing emphasis on candidates’ differences as the debates wear on.

Combining all the data, we get an indication of how people tended to interact throughout the debates:

In[]:=

Thread[candidatescolorList@debateMentionsGraph[Flatten@allDebateData]]

Out[]=



Amy Klobuchar



Andrew Yang



Bernie Sanders



Beto O'Rourke



Bill de Blasio



Cory Booker



Elizabeth Warren



Eric Swalwell



Jay Inslee



Joe Biden



John Delaney



John Hickenlooper



Julián Castro



Kamala Harris



Kirsten Gillibrand



Marianne Williamson



Michael Bennet



Pete Buttigieg



Steve Bullock



Tim Ryan



Tulsi Gabbard



Tom Steyer





Again, the data tells a story. Biden, the long-time presumptive frontrunner, receives a lot more attention than he gives. Many of the minor candidates—Bullock, Inslee, Delaney—tend to (or rather, are able to) call out others without getting much return fire. One almost gets the impression that Tom Steyer is only in the race because of his assertiveness!

Polling: Who Gained the Most Voters? If there’s one metric most analysts can agree upon (or at least, agree to criticize), it’s the national polls. So if we want some objective measure of who “won” the debate, that might be a good place to start. Much of this section is probably similar to standard analyses you’ll find elsewhere.

For this section, we'll jump back into text analytics; I found a Wikipedia article rife with up-to-date info in organized tables:

In[]:=

pollData=Import["https://wolfr.am/K7iT0dHR","Data"];

Each row contains the same information—dates administered, sample size, margin of error and percentages for each candidate. Using

StringTrim

to get rid of unnecessary characters, here is a function to parse the data from each list and interpret it with

SemanticImportString

In[]:=

parsePollData[list_]:=SemanticImportString[ExportString[Select[StringTrim[#,{Shortest["–"|"-"~~___~~DigitCharacter..],"± ",("("|"[")~~__~~(")"|"]")~~WhitespaceCharacter...}]&/@list//Quiet,Length[#]Length[list[[1]]]&],"CSV",CharacterEncoding"ASCII"],PadRight[{"String",Interpreter@"Date","Number","Percent"},Length[list[[1]]],"Percent"],HeaderLines1]

The page includes a lot of extra info—and it keeps growing—but we’re mainly interested in polls between last June and today. Here is a combined list of all entries from that window:

In[]:=

pollDataCombined=Flatten@Table[Normal@parsePollData[p],{p,pollData[[1,5;;13]]}];

Now we have entries for each poll, but all the dates are interpreted as being in 2020:

In[]:=

RandomChoice[pollDataCombined]

Out[]=

Poll sourceTheHillHarrisX,Date(s) administered

Day: Sun 12 Jul 2020

,Sample size446,Margin of error

3.1

,Joe Biden

,Pete Buttigieg

,Kamala Harris

,Beto O'Rourke

,Bernie Sanders

,Elizabeth Warren

,Other

,Undecided



As a final cleaning step, we’ll fix the dates and standardize the key names:

In[]:=

cleanPollData[list_]:=Table[KeyMap[StringReplace[StringTrim[#],{___~~"source"~~___"Source",___~~"date"~~___"Date",___~~"size"~~___"SampleSize",___~~"err"~~___"ErrorMargin",___~~"undecided"~~___"Undecided"},IgnoreCaseTrue]&,p]//If[#Date>Today,#/.#Date(#Date-

),#]&,{p,list}]

In[]:=

pollDataClean=cleanPollData[pollDataCombined];

With this dataset, we can view polling numbers for a given candidate or date range. Here is each candidate’s polling history as a

TimeSeries

object:

In[]:=

pollNames=Intersection[candidateNames,Union[Flatten[Keys/@pollDataClean]]];

In[]:=

pollHistory=Table[cTimeSeries[Values/@DeleteMissing[pollDataClean[[All,{"Date",c}]],1,2]],{c,pollNames}];

The data is summed up nicely by a

DateListPlot

In[]:=

DateListPlot[Thread@Legended[TimeSeriesResample[Values@pollHistory,

],Last/@StringSplit/@pollNames]]

Out[]=

	Klobuchar
	Yang
	Sanders
	O'Rourke
	Booker
	Warren
	Biden
	Harris

	Buttigieg
	Steyer
	Gabbard

However, this overview includes more information than we need, and many of the lower-polling candidates are obscured. Let’s zoom in to only look at the leaders, i.e. anyone who has risen above 10% in the polls since the debates began:

In[]:=

leaders=Select[pollHistory,ContainsAny[Union[#>

&/@Values[#[[2]]]],{True}]&];

By adding vertical lines for each debate date, we can get a rough idea of how the debates have affected polling:

In[]:=

DateListPlotLegendedTimeSeriesResample[Values@leaders,

Last Names

//Thread,

Options



Out[]=

	Sanders
	Warren
	Biden
	Harris
	Buttigieg

Though the rankings haven’t moved much, you can see a few peaks and troughs that likely resulted from debates. For a quick estimate of who might have gained or lost, we can aggregate data from the week before a debate, then compare to polling numbers the week after the same debate:

In[]:=

beforeAfter[date_,data_:pollDataClean]:=With[{before=Select[data,date≥#Date>date-

&],after=Select[data,date≤#Date<date+

&]},DeleteCases[<|Table[cN@Mean[Cases[#[[All,c]],_Quantity]],{c,pollNames}]/.Thread[candidateNamescandidates]|>,_Mean]&/@{before,after}]

Subtracting the two values gives an estimate of percentage changes around a given date:

In[]:=

percentChange[date_,data_:pollDataClean]:=Subtract@@Reverse@beforeAfter[date,data]

From there, we can use the mean polling per candidate to judge whether public opinion shifted. For instance, Kamala Harris’s average went up significantly after the first debate in June:

In[]:=

percentChange[DateObject[{2019,6,26}]]

Out[]=



Bernie Sanders



-0.407143

Beto O'Rourke



-0.760714

Cory Booker



0.67

Elizabeth Warren



-2.81071

Joe Biden



-2.98214

Kamala Harris



7.37857

Pete Buttigieg



0.742857



This should give a broad measure of how debate performance affected polling for each candidate. Here are the numbers for the latest debate—only including those candidates who actually participated:

In[]:=

KeySelectpercentChange

Day: Tue 14 Jan 2020

,MemberQ[Union@Keys@d7Data,#]&



Amy Klobuchar



0.685714

Bernie Sanders



2.13333

Elizabeth Warren



0.533333

Joe Biden



2.13333

Pete Buttigieg



0.428571

Tom Steyer



0.0857143



Iowa Caucus and Beyond Of course, none of these numbers really mean anything until voting starts. The first candidate selection event of the cycle, the Iowa caucus, was held earlier this week—with Pete Buttegieg appearing to come out on top (pending final results).

Let’s see how this compares with our debate mentions. We’ll need to get a dataset of statewide polling:

In[]:=

stateData=Import["https://wolfr.am/K7juP63d","Data"];

Using the functions from the previous section, we can import the most recent Iowa polls:

In[]:=

iowaPollData=Normal@parsePollData[stateData[[1,5]]]//cleanPollData;

As in the previous section, we grab the polling history for each candidate:

In[]:=

iowaNames=Intersection[candidateNames,Union[Flatten[Keys/@iowaPollData]]];

In[]:=

iowaHistory=Table[cTimeSeries[Values/@DeleteMissing[iowaPollData[[All,{"Date",c}]],1,2]],{c,iowaNames}];

The polling history shows that the rankings changed drastically after the Iowa debate:

In[]:=

DateListPlotThread@LegendedTimeSeriesResampleValues@iowaHistory,

days

,Last/@StringSplit/@iowaNames,

Options



Out[]=

	Klobuchar
	Yang
	Sanders
	Warren
	Biden
	Buttigieg
	Steyer
	Gabbard

Sanders and Biden have been battling for the top spot in Iowa, but Buttigieg and Warren came in with some potential too. Sanders had the biggest polling surge in the weeks leading up to the caucus:

In[]:=

percentChange[DateObject[{2020,1,20}],iowaPollData]

Out[]=



Amy Klobuchar



-1.63333

Andrew Yang



0.8

Bernie Sanders



5.9

Elizabeth Warren



0.855556

Joe Biden



0.433333

Pete Buttigieg



-0.655556

Tom Steyer



0.24

Tulsi Gabbard



0.46



Going by the standard analysis, Sanders or Biden should obviously have come out on top. But referring back to the centrality graph from earlier, Buttigieg was actually the most “popular” in that others mentioned him without him ever mentioning anyone else:

In[]:=

facesOverlay[debateMentionsGraph[d7Data]]

Out[]=

Perhaps ignoring critics was a winning strategy in that case!

Graph theory is a useful lens for visualizing interpersonal exchanges, providing some unique computational insights about how the candidates interact. Combining this with other computations could provide even more interesting information, such as using sentiment analysis to determine candidates’ attitudes toward each other. In the coming months, it will be interesting to find out what kinds of debaters end up winning the most primaries: assertive, popular or mixed. Try it yourself—maybe you can define your own computational measure of a debate winner!

Cite this as: Brian Wood, "Democratic Presidential Debate Analysis Using the Wolfram Language" from the Notebook Archive (2020), https://notebookarchive.org/2020-02-39c6igj